报告服务器游标的特性。

语法

sp_describe_cursor [ @cursor_return = ] output_cursor_variable OUTPUT

    { [ , [ @cursor_source = ] N'local'

        , [ @cursor_identity = ] N'local_cursor_name' ]

            | [ , [ @cursor_source = ] N'global'

        , [ @cursor_identity = ] N'global_cursor_name' ]

            | [ , [ @cursor_source = ] N'variable'

        , [ @cursor_identity = ] N'input_cursor_variable' ]

    }

参数

[@cursor_return =] output_cursor_variable OUTPUT

声明游标变量的名称，该变量接收游标输出。output_cursor_variable 的数据类型为 cursor，没有默认值。调用 sp_describe_cursor 时，不能与任何游标相关联。返回的游标是可滚动的动态只读游标。

[@cursor_source =] { N'local' | N'global' | N'variable' }

指定是使用本地游标的名称、全局游标的名称、还是游标变量的名称来指定当前正在对其进行报告的游标。参数是 nvarchar(30)。

[@cursor_identity =] N'local_cursor_name']

由具有 LOCAL 关键字或默认设置为 LOCAL 的 DECLARE CURSOR 语句创建的游标的名称。local_cursor_name 的数据类型为 nvarchar(128)。

[@cursor_identity =] N'global_cursor_name']

由具有 GLOBAL 关键字或默认设置为 GLOBAL 的 DECLARE CURSOR 语句创建的游标的名称。也可以是由 ODBC 应用程序打开然后通过调用 SQLSetCursorName 对游标命名的 API 服务器游标的名称。global_cursor_name 的数据类型为 nvarchar(128)。

[@cursor_identity =] N'input_cursor_variable']

与开放游标相关联的游标变量的名称。input_cursor_variable 的数据类型为 nvarchar(128)。

返回代码值

无

返回的游标

sp_describe_cursor 将结果集封装在 Transact-SQL cursor 输出参数中。这样，Transact-SQL 批处理、存储过程和触发器就得以按一次一行的方式处理输出。它还意味着无法直接从数据库 API 函数直接调用该过程。cursor 输出参数必须绑定到程序变量，但是数据库 API 不支持绑定 cursor 参数或变量。

下面是 sp_describe_cursor 返回的游标格式。游标格式与 sp_cursor_list 返回的格式相同。

注释

sp_describe_cursor 描述服务器游标的全局特性，比如滚动和更新的能力。使用 sp_describe_cursor_columns 描述由游标返回的结果集的特性。使用 sp_describe_cursor_tables 报告游标所引用的基表。使用 sp_cursor_list 可获得连接时可视的 Transact-SQL 服务器游标的报告。

DECLARE CURSOR 语句可能会请求一个 Microsoft® SQL Server™ 使用 DECLARE CURSOR 中包含的 SELECT 语句不能支持的游标类型。SQL Server 隐式地将游标转换成支持 SELECT 语句的类型。如果在 DECLARE CURSOR 语句中指定 TYPE_WARNING，SQL Server 向应用程序发送一条转换完毕的消息。然后就可以调用 sp_describe_cursor 确定已实现的游标类型。

权限

执行权限默认赋予 public 角色。

示例

下面的示例打开一个全局游标，并使用 sp_describe_cursor 报告游标的特性。

USE Northwind

GO
-- Declare and open a global cursor.
DECLARE abc CURSOR STATIC FOR
SELECT LastName
FROM Employees

OPEN abc

-- Declare a cursor variable to hold the cursor output variable
-- from sp_describe_cursor.
DECLARE @Report CURSOR

-- Execute sp_describe_cursor into the cursor variable.
EXEC master.dbo.sp_describe_cursor @cursor_return = @Report OUTPUT,
        @cursor_source = N'global', @cursor_identity = N'abc'

-- Fetch all the rows from the sp_describe_cursor output cursor.
FETCH NEXT from @Report
WHILE (@@FETCH_STATUS <> -1)
BEGIN
    FETCH NEXT from @Report
END

-- Close and deallocate the cursor from sp_describe_cursor.
CLOSE @Report
DEALLOCATE @Report
GO

-- Close and deallocate the original cursor.
CLOSE abc
DEALLOCATE abc
GO